Day 10: Pipe Maze

Megathread guidelines

  • Keep top level comments as only solutions, if you want to say something other than a solution put it in a new post. (replies to comments can be whatever)
  • Code block support is not fully rolled out yet but likely will be in the middle of the event. Try to share solutions as both code blocks and using something such as https://topaz.github.io/paste/ , pastebin, or github (code blocks to future proof it for when 0.19 comes out and since code blocks currently function in some apps and some instances as well if they are running a 0.19 beta)

FAQ

🔒 Thread is locked until there’s at least 100 2 star entries on the global leaderboard

🔓 Unlocked after 40 mins

  • vole@lemmy.worldEnglish
    1·
    1 year ago

    Raku

    My solution for today is quite sloppy. For part 2, I chose to color along both sides of the path (each side different colors) and then doing a fill of the empty space based on what color the empty space is touching. Way less optimal than scanning, and I didn’t cover every case for coloring around the start point, but it was interesting to attempt. I ran into a bunch of issues on dealing with nested arrays in Raku, I need to investigate if there’s a better way to handle them.

    View code on github

    Edit: did some cleanup, added some fun, and switched to the scanning algorithm for part 2, shaved off about 50 lines of code.

    Code 
    use v6;

sub MAIN($input) {
    my $file = open $input;

    my @map = $file.lines».comb».Array;

    my @starting-point = @map».grep('S', :k)».[0].grep(*.defined, :kv).List;

    my @path = (@starting-point,);

    my %tile-neighbors =
        '|' => (( 1, 0),(-1, 0)),
        '-' => (( 0,-1),( 0, 1)),
        'L' => ((-1, 0),( 0, 1)),
        'J' => ((-1, 0),( 0,-1)),
        '7' => (( 1, 0),( 0,-1)),
        'F' => (( 1, 0),( 0, 1)),
    ;

    sub connecting-neighbor(@position, @neighbor) {
        my @neighbor-position = @position Z+ @neighbor;
        return False if any(@neighbor-position Z< (0, 0));
        return False if any(@neighbor-position Z> (@map.end, @map.head.end));
        my $neighbor-tile = @map[@neighbor-position[0]; @neighbor-position[1]];
        my @negative-neighbor = @neighbor X* -1;
        return %tile-neighbors{$neighbor-tile}.grep(@negative-neighbor, :k).elems > 0;
    }

    # replace starting-point with the appropriate pipe
    my @start-tile-candidates = <| - L J 7 F>;
    for @start-tile-candidates -> $candidate {
        next if %tile-neighbors{$candidate}.map({!connecting-neighbor(@starting-point, $_)}).any;
        @map[@starting-point[0]; @starting-point[1]] = $candidate;
        last;
    }

    repeat {
        my @position := @path.tail;
        my $tile = @map[@position[0]; @position[1]];
        my @neighbors = %tile-neighbors{$tile}.List;
        for @neighbors -> @neighbor {
            my @neighbor-position = @neighbor Z+ @position;
            next if @path.elems >= 2 && @neighbor-position eqv @path[*-2];
            if connecting-neighbor(@position, @neighbor) {
                @path.push(@neighbor-position);
                last;
            }
        }
    } while @path.tail !eqv @path.head;
    my $part-one-solution = (@path.elems / 2).floor;
    say "part 1: {$part-one-solution}";

    my %pipe-set = @path.Set;
    my %same-side-pairs = ;
    my $part-two-solution = 0;
    for ^@map.elems -> $y {
        my $inside = False;
        my $entrance-pipe = Nil;
        for ^@map.head.elems -> $x {
            if %pipe-set{$($y, $x)} {
                given @map[$y; $x] {
                    when '|' { $inside = !$inside }
                    when 'F' | 'L' { $entrance-pipe = $_ }
                    when 'J' | '7' {
                        $inside = !$inside if %same-side-pairs{$entrance-pipe} ne $_;
                        $entrance-pipe = Nil;
                    }
                }
            } elsif $inside {
                $part-two-solution += 1;
            }
        }
    }
    say "part 2: $part-two-solution";
}